config.m4

AC_ARG_VAR([DDTRACE_PROFILING_FEATURES], [additional Cargo features for standalone profiler test builds])
AC_ARG_VAR([DDTRACE_PROFILING_CARGO_BUILD_FLAGS], [additional Cargo build flags for the standalone profiler])
AC_ARG_VAR([DDTRACE_PROFILING_TARGET], [Rust target triple for the standalone profiler])

PHP_ARG_ENABLE(ddtrace, whether to enable Datadog support,
  [  --enable-ddtrace   Enable Datadog tracing support])

PHP_ARG_ENABLE(ddtrace-tracer, whether to enable Datadog tracing support,
  [  --disable-ddtrace-tracer Disable Datadog tracing support], yes, no)

PHP_ARG_ENABLE(ddtrace-profiling, whether to build the standalone Datadog profiler,
  [  --enable-ddtrace-profiling Build the standalone datadog-profiling extension], no, no)

PHP_ARG_ENABLE(ddtrace-sanitize, whether to enable AddressSanitizer for ddtrace,
  [  --enable-ddtrace-sanitize Build Datadog tracing with AddressSanitizer support], no, no)

PHP_ARG_WITH(ddtrace-rust-library, the rust library is located; i.e. to compile without cargo,
  [  --with-ddtrace-rust-library Location to rust library for linking against], -, will be compiled)

PHP_ARG_WITH(ddtrace-sidecar-mockgen, binary to weaken PHP symbols in object files,
  [  --with-ddtrace-sidecar-library Location to cargo binary produced by components-rs/php_sidecar_mockgen], -, will be compiled)

PHP_ARG_WITH(ddtrace-cargo, where cargo is located for rust code compilation,
  [  --with-ddtrace-cargo Location to cargo binary for rust compilation], cargo, not found)

PHP_ARG_ENABLE(ddtrace-rust-debug, whether to compile rust in debug mode,
  [  --enable-ddtrace-rust-debug Build rust code in debug mode (significantly slower)], [[$( (if test x"$ext_shared" = x"yes"; then $GREP -q "ZEND_DEBUG 1" $("$PHP_CONFIG" --include-dir)/main/php_config.h; else test x"$PHP_DEBUG" = x"yes"; fi) && echo yes || echo no)]], [no])

PHP_ARG_ENABLE(ddtrace-rust-library-split, whether to keep the rust library separate from the extension,
  [  --enable-ddtrace-rust-library-split Do not build or statically link the rust code], no, no)

DDTRACE_PHP_CONFIG=$(command -v "$PHP_CONFIG" 2>/dev/null || echo "$PHP_CONFIG")
PHP_SUBST(DDTRACE_PHP_CONFIG)

dnl Keep make clean out of Cargo targets; distclean removes all product-specific targets.
AC_DEFUN([DDTRACE_GEN_GLOBAL_MAKEFILE_WRAP], [
  pushdef([PHP_GEN_GLOBAL_MAKEFILE], [
    popdef([PHP_GEN_GLOBAL_MAKEFILE])
    PHP_GEN_GLOBAL_MAKEFILE
    [sed -i $({ sed --version 2>&1 || echo ''; } | grep GNU >/dev/null || echo "''") -e '/.*\.[ao] /{s/| xargs rm -f/! -path ".\/target*\/*" | xargs rm -f/'$'\n}' -e '/^distclean:/a\'$'\n\t''rm -rf target-common/ target-profiling/ target_mockgen/' Makefile]
    DDTRACE_GEN_GLOBAL_MAKEFILE_WRAP
  ])
])
DDTRACE_GEN_GLOBAL_MAKEFILE_WRAP

if test "$PHP_DDTRACE_TRACER" != "no" && test "$PHP_DDTRACE_PROFILING" != "no"; then
  AC_MSG_ERROR([A combined tracer and profiler extension is deferred to a later milestone. Build the standalone profiler with: ./configure --disable-ddtrace-tracer --enable-ddtrace-profiling])
fi

if test "$PHP_DDTRACE_PROFILING" != "no"; then
  dnl PHP_NEW_EXTENSION normally initializes this for libtool's configure probes.
  RM="rm -f"

  case "$host_os" in
    mingw*|cygwin*|msys*|windows*)
      AC_MSG_ERROR([The standalone Datadog profiler is not supported on Windows])
      ;;
  esac

  if test -z ${PHP_VERSION_ID+x}; then
    PHP_VERSION_ID=$("$PHP_CONFIG" --vernum)
  fi
  if test "$PHP_VERSION_ID" -lt 70100; then
    AC_MSG_ERROR([The standalone Datadog profiler requires PHP 7.1 or newer; PHP 7.0 is not supported])
  fi

  if test -n "$PHP_DDTRACE_CARGO" && test "$PHP_DDTRACE_CARGO" != "cargo"; then
    if test -x "$PHP_DDTRACE_CARGO"; then
      DDTRACE_CARGO="$PHP_DDTRACE_CARGO"
    else
      AC_MSG_ERROR([$PHP_DDTRACE_CARGO is not an executable])
    fi
  else
    AC_CHECK_TOOL(DDTRACE_CARGO, cargo, [:])
    AS_IF([test "$DDTRACE_CARGO" = ":"], [AC_MSG_ERROR([Please install cargo before configuring, or specify it with --with-ddtrace-cargo=])])
  fi
  PHP_SUBST(DDTRACE_CARGO)

  profiler_cargo_profile=$(test "$PHP_DDTRACE_RUST_DEBUG" != "no" && echo debug || echo profiler-release)
  profiler_target_dir="${CARGO_TARGET_DIR:-\$(builddir)/target-profiling}"
  profiler_target_path=
  profiler_target_arg=
  if test -n "$DDTRACE_PROFILING_TARGET"; then
    profiler_target_path="/$DDTRACE_PROFILING_TARGET"
    profiler_target_arg="--target $DDTRACE_PROFILING_TARGET"
  fi
  case "$host_os" in
    darwin*) profiler_rust_suffix=dylib ;;
    *) profiler_rust_suffix=so ;;
  esac
  profiler_rust_lib="$profiler_target_dir$profiler_target_path/$profiler_cargo_profile/libdatadog_php.$profiler_rust_suffix"
  dnl Register the Rust cdylib with the ordinary module build and install targets.
  PHP_MODULES="$PHP_MODULES \$(phplibdir)/datadog-profiling.la"
  PHP_SUBST(PHP_MODULES)

  cat <<EOT >> Makefile.fragments
$profiler_rust_lib: \$(shell for dir in \$(srcdir)/components-rs \$(srcdir)/profiling \$(srcdir)/libdatadog \$(srcdir)/../../libdatadog; do test ! -d \$\$dir || find \$\$dir \( -type f -o -type l \) \( -name '*.rs' -o -name '*.c' -o -name '*.h' -o -name Cargo.toml \) -not -path '*/target/*' -not -path '*/.git/*'; done) \$(srcdir)/ext/handlers_api.c \$(srcdir)/ext/handlers_api.h \$(srcdir)/Cargo.toml \$(srcdir)/Cargo.lock \$(srcdir)/VERSION
	(cd "\$(srcdir)"; PHP_CONFIG="\$(DDTRACE_PHP_CONFIG)" CARGO_TARGET_DIR="$profiler_target_dir" RUSTFLAGS="\$(RUSTFLAGS) --cfg tokio_unstable" "\$(DDTRACE_CARGO)" build $DDTRACE_PROFILING_CARGO_BUILD_FLAGS $profiler_target_arg --no-default-features --features "profiling${DDTRACE_PROFILING_FEATURES:+,$DDTRACE_PROFILING_FEATURES}" $(test "$profiler_cargo_profile" = debug || echo --profile "$profiler_cargo_profile") \$(shell echo "\$(MAKEFLAGS)" | $EGREP -o "[[-]]j[[0-9]]+"))

\$(phplibdir)/datadog-profiling.la: $profiler_rust_lib
	@mkdir -p \$(phplibdir)/.libs
	cp $profiler_rust_lib \$(phplibdir)/datadog-profiling.so
	cp $profiler_rust_lib \$(phplibdir)/.libs/datadog-profiling.so
	@printf '%s\n' "# datadog-profiling.la - generated by configure" "dlname='datadog-profiling.so'" "library_names='datadog-profiling.so'" "old_library=''" "dependency_libs=''" "installed=no" "shouldnotlink=no" "dlopen=''" "dlpreopen=''" "libdir='\$(phplibdir)'" > \$@

clean-profiler:
	rm -f \$(phplibdir)/datadog-profiling.la \$(phplibdir)/datadog-profiling.so \$(phplibdir)/.libs/datadog-profiling.so
clean: clean-profiler

EOT
fi

if test "$PHP_DDTRACE" != "no" && test "$PHP_DDTRACE_PROFILING" = "no"; then
  AC_CHECK_SIZEOF([long])
  AC_MSG_CHECKING([for 64-bit platform])
  AS_IF([test "$ac_cv_sizeof_long" -eq 4],[
    AC_MSG_RESULT([no])
    AC_MSG_ERROR([ddtrace only supports 64-bit platforms])
  ],[
    AC_MSG_RESULT([yes])
  ])

  define(DDTRACE_BASEDIR, esyscmd(printf %s "$(dirname "__file__")"))
  m4_include(DDTRACE_BASEDIR/m4/polyfill.m4)
  m4_include(DDTRACE_BASEDIR/m4/ax_execinfo.m4)
  m4_include(DDTRACE_BASEDIR/m4/threads.m4)

  AX_EXECINFO

  AS_IF([test x"$ac_cv_header_execinfo_h" = xyes],
    dnl This duplicates some of AX_EXECINFO's work, but AX_EXECINFO puts the
    dnl library into LIBS, which we don't use anywhere else and am worried that
    dnl it may contain things we are not expecting aside from execinfo
    PHP_CHECK_LIBRARY(execinfo, backtrace,
      [PHP_ADD_LIBRARY(execinfo, , EXTRA_LDFLAGS)])
  )

  AC_CHECK_HEADERS([linux/securebits.h])
  AC_CHECK_HEADERS([linux/capability.h])
  AC_CHECK_HEADERS([valgrind/valgrind.h])

  dnl
  m4_ifndef([_LT_CHECK_OBJDIR], AC_LIBTOOL_OBJDIR, _LT_CHECK_OBJDIR)

  if test "$PHP_DDTRACE_RUST_LIBRARY" = "-" || test "$PHP_DDTRACE_SIDECAR_MOCKGEN" = "-"; then
    if test -n "$PHP_DDTRACE_CARGO" && test "$PHP_DDTRACE_CARGO" != "cargo"; then
      if test -x "$PHP_DDTRACE_CARGO"; then
        DDTRACE_CARGO="$PHP_DDTRACE_CARGO"
      else
        AC_MSG_ERROR([$PHP_DDTRACE_CARGO is not an executable])
      fi
    else
      AC_CHECK_TOOL(DDTRACE_CARGO, cargo, [:])
      AS_IF([test "$DDTRACE_CARGO" = ":"], [AC_MSG_ERROR([Please install cargo before configuring, or specify it with --with-ddtrace-cargo=])])
    fi
    PHP_SUBST(DDTRACE_CARGO)
  fi

  if test "$PHP_DDTRACE_SANITIZE" != "no"; then
    dnl gcc needs -lasan, clang needs -shared-libsan
    ac_cflags=$LDFLAGS
    LDFLAGS=-shared-libsan
    AC_RUN_IFELSE([AC_LANG_SOURCE([[int main(void) { return (0); }]])],[found=yes],[found=no],[found=yes])
    LDFLAGS=$ac_ldflags

    EXTRA_LDFLAGS="-fsanitize=address $(if test $found = "yes"; then echo "-shared-libsan -lclang_rt.asan-$(uname -m)"; else echo "-lasan"; fi)"
    EXTRA_CFLAGS="-fsanitize=address -fno-omit-frame-pointer"
  fi

  CFLAGS="$CFLAGS -fms-extensions"
  EXTRA_CFLAGS="$EXTRA_CFLAGS -fms-extensions"

  rm="rm -f"
  lt_simple_link_test_code='int main(void){return(0);}'
  AC_MSG_CHECKING([whether --undefined-version is a valid linker argument])
  AC_LIBTOOL_LINKER_OPTION([whether --undefined-version is a valid linker argument],
    lt_cv_ddtrace_undefined_version,
    [-Wl,--undefined-version],
    [LDFLAGS="$LDFLAGS -Wl,--undefined-version"])

  lt_simple_compile_test_code="int some_variable = 0;"
  Xsed="$SED -e 1s/^X//"
  AC_LIBTOOL_COMPILER_OPTION([whether -Wno-microsoft-anon-tag is a valid compiler argument],
    lt_cv_ddtrace_no_microsoft_anon_tag,
    [-Wno-microsoft-anon-tag], [],
    [
      CFLAGS="$CFLAGS -Wno-microsoft-anon-tag"
      EXTRA_CFLAGS="$EXTRA_CFLAGS -Wno-microsoft-anon-tag"
    ])

  case "$host_os:$host_cpu" in
    linux*:x86_64)
      AC_LIBTOOL_COMPILER_OPTION([whether -mtls-dialect=gnu2 is a valid compiler argument],
        lt_cv_ddtrace_tls_dialect_gnu2,
        [-mtls-dialect=gnu2], [],
        [
          CFLAGS="$CFLAGS -mtls-dialect=gnu2"
          EXTRA_CFLAGS="$EXTRA_CFLAGS -mtls-dialect=gnu2"
        ],
        [AC_MSG_ERROR([x86-64 Linux OTel context sharing requires compiler support for -mtls-dialect=gnu2])])
      ;;
  esac

  DD_TRACE_VENDOR_SOURCES="\
    tracer/vendor/mpack/mpack.c \
    tracer/vendor/mt19937/mt19937-64.c \
    src/dogstatsd/client.c \
  "

  DATADOG_COMPONENT_SOURCES="\
    components/log/log.c \
    components/sapi/sapi.c \
    components/string_view/string_view.c \
  "

  if test -z ${PHP_VERSION_ID+x}; then
    PHP_VERSION_ID=$("$PHP_CONFIG" --vernum)
  fi

  EXTRA_DATADOG_SOURCES=""

  if test $PHP_VERSION_ID -lt 70000; then
    dnl PHP 5
    echo "PHP 5 is not supported on this branch. Use the PHP-5 branch to build PHP 5."
    exit 1
  elif test $PHP_VERSION_ID -lt 80000; then
    dnl PHP 7.x

    EXTRA_TRACER_SOURCES="tracer/handlers_curl_php7.c"

    if test $PHP_VERSION_ID -lt 70300; then
      EXTRA_DATADOG_SOURCES="$EXTRA_DATADOG_SOURCES \
        ext/zend_hrtime.c"
    fi

    EXTRA_ZAI_SOURCES="\
      zend_abstract_interface/interceptor/php7/interceptor.c \
      zend_abstract_interface/interceptor/php7/resolver.c \
      zend_abstract_interface/sandbox/php7/sandbox.c \
    "
  elif test $PHP_VERSION_ID -lt 90000; then
    dnl PHP 8.x
    EXTRA_TRACER_SOURCES="\
        tracer/handlers_curl.c \
        tracer/hook/uhook_attributes.c \
        tracer/hook/uhook_otel.c \
    "
    ZAI_RESOLVER_SUFFIX=""

    if test $PHP_VERSION_ID -lt 80200; then
      ZAI_RESOLVER_SUFFIX="_pre-8_2"
      EXTRA_TRACER_SOURCES="$EXTRA_TRACER_SOURCES \
        tracer/weakrefs.c"

      EXTRA_DATADOG_SOURCES="$EXTRA_DATADOG_SOURCES \
        ext/patch_zend_call_known_function.c"
    fi

    if test $PHP_VERSION_ID -ge 80100; then
      EXTRA_TRACER_SOURCES="$EXTRA_TRACER_SOURCES \
        tracer/handlers_fiber.c"
    fi

    EXTRA_ZAI_SOURCES="\
      zend_abstract_interface/interceptor/php8/interceptor.c \
      zend_abstract_interface/interceptor/php8/resolver$ZAI_RESOLVER_SUFFIX.c \
      zend_abstract_interface/jit_utils/jit_blacklist.c \
      zend_abstract_interface/sandbox/php8/sandbox.c \
    "
  fi

  case "$host_os" in
    linux*)
      EXTRA_TRACER_SOURCES="$EXTRA_TRACER_SOURCES tracer/otel_context.c"
      ;;
  esac

  dnl datadog.c/ddtrace.c comes first, then everything else alphabetically
  DATADOG_PHP_SOURCES="$EXTRA_DATADOG_SOURCES \
    ext/datadog.c
    ext/agent_info.c \
    ext/compat_getrandom.c \
    ext/configuration.c \
    ext/crashtracking_frames.c \
    ext/endpoints.c \
    ext/excluded_modules.c \
    ext/git.c \
    ext/handlers_api.c \
    ext/handlers_pcntl.c \
    ext/handlers_signal.c \
    ext/logging.c \
    ext/otel_config.c \
    ext/phpinfo.c \
    ext/process_tags.c \
    ext/remote_config.c \
    ext/sidecar.c \
    ext/signals.c \
    ext/startup_logging.c \
    ext/string_utils.c \
    ext/target_metadata.c \
    ext/telemetry.c \
    ext/threads.c \
  "

  DATADOG_TRACER_SOURCES="$EXTRA_TRACER_SOURCES \
    tracer/ddtrace.c \
    tracer/asm_event.c \
    tracer/auto_flush.c \
    tracer/autoload_php_files.c \
    tracer/code_origins.c \
    tracer/collect_backtrace.c \
    tracer/comms_php.c \
    tracer/coms.c \
    tracer/distributed_tracing_headers.c \
    tracer/dogstatsd_client.c \
    tracer/endpoint_guessing.c \
    tracer/engine_api.c \
    tracer/engine_hooks.c \
    tracer/exception_serialize.c \
    tracer/ffe.c \
    tracer/functions.c \
    tracer/git_metadata.c \
    tracer/handlers_exception.c \
    tracer/handlers_httpstreams.c \
    tracer/handlers_internal.c \
    tracer/handlers_kafka.c \
    tracer/inferred_proxy_headers.c \
    tracer/integrations/exec_integration.c \
    tracer/integrations/integrations.c \
    tracer/ip_extraction.c \
    tracer/live_debugger.c \
    tracer/limiter/limiter.c \
    tracer/memory_limit.c \
    tracer/tracer_otel_config.c \
    tracer/priority_sampling/priority_sampling.c \
    tracer/profiling.c \
    tracer/random.c \
    tracer/rule_matching.c \
    tracer/serializer.c \
    tracer/standalone_limiter.c \
    tracer/span.c \
    tracer/span_stats.c \
    tracer/trace_filter.c \
    tracer/trace_source.c \
    tracer/tracer_startup_logging.c \
    tracer/tracer_tag_propagation/tracer_tag_propagation.c \
    tracer/tracer_telemetry.c \
    tracer/user_request.c \
    tracer/weak_resources.c \
    tracer/hook/uhook.c \
    tracer/hook/uhook_legacy.c \
  "

  ZAI_SOURCES="$EXTRA_ZAI_SOURCES \
    zend_abstract_interface/config/config.c \
    zend_abstract_interface/config/config_decode.c \
    zend_abstract_interface/config/config_ini.c \
    zend_abstract_interface/config/config_stable_file.c \
    zend_abstract_interface/config/config_runtime.c \
    zend_abstract_interface/env/env.c \
    zend_abstract_interface/exceptions/exceptions.c \
    zend_abstract_interface/headers/headers.c \
    zend_abstract_interface/hook/hook.c \
    zend_abstract_interface/json/json.c \
    zend_abstract_interface/sandbox/call.c \
    zend_abstract_interface/uri_normalization/uri_normalization.c \
    zend_abstract_interface/zai_string/string.c \
  "

  DATADOG_EXTENSION_FLAGS="-DZEND_ENABLE_STATIC_TSRMLS_CACHE=1 -Wall -std=gnu11"

  ALL_DATADOG_SOURCES=" \
    $DATADOG_PHP_SOURCES \
    $ZAI_SOURCES \
    $DATADOG_COMPONENT_SOURCES \
  "

  if test "$PHP_DDTRACE_TRACER" != "no"; then
    ALL_DATADOG_SOURCES="$ALL_DATADOG_SOURCES \
      $DD_TRACE_VENDOR_SOURCES \
      $DATADOG_TRACER_SOURCES \
      $DD_TRACE_PHP_SOURCES
    "

    DATADOG_EXTENSION_FLAGS="$DATADOG_EXTENSION_FLAGS -DDDTRACE"
  fi

  PHP_NEW_EXTENSION(ddtrace, $ALL_DATADOG_SOURCES, $ext_shared,, $DATADOG_EXTENSION_FLAGS)
  PHP_ADD_BUILD_DIR($ext_builddir/ext, 1)

  dnl sidecar requires us to be linked against libm for pow and powf and librt for shm_* functions
  AC_CHECK_LIBM
  dnl Deliberately not in EXTRA_LDFLAGS: those land before libdatadog_php.a on
  dnl the link line, so they would not satisfy its undefined symbols. Note that
  dnl the relinks in .gitlab/compile_extension.sh and
  dnl .gitlab/link-tracing-extension.sh are driven solely by
  dnl ddtrace-fat.ldflags
  dnl and add no libm of their own, so it has to be in that file too.
  EXTRA_LIBS="$EXTRA_LIBS $LIBM"
  DDTRACE_SHARED_LIBADD="${DDTRACE_SHARED_LIBADD:-} $LIBM"
  ddtrace_ldflags_file_extra="$ddtrace_ldflags_file_extra $LIBM"
  dnl as well as explicitly for pthread_atfork
  PTHREADS_CHECK
  EXTRA_CFLAGS="$EXTRA_CFLAGS $ac_cv_pthreads_cflags"
  EXTRA_LIBS="$EXTRA_LIBS -l$ac_cv_pthreads_lib"
  PHP_CHECK_LIBRARY(rt, shm_open,
    [EXTRA_LDFLAGS="$EXTRA_LDFLAGS -lrt"; DDTRACE_SHARED_LIBADD="${DDTRACE_SHARED_LIBADD:-} -lrt"])

  dnl rust imports these, so we need them to link
  case $host_os in
   darwin*)
    EXTRA_LDFLAGS="$EXTRA_LDFLAGS -framework CoreFoundation -framework Security"
    PHP_ADD_FRAMEWORK([CoreFoundation])
    PHP_ADD_FRAMEWORK([Security])
    PHP_SUBST(EXTRA_LDFLAGS)
  esac

  PHP_CHECK_LIBRARY(curl, curl_easy_setopt,
    [case " $LDFLAGS " in
       *" -Wl,-Bdynamic "*)
         EXTRA_LDFLAGS="$EXTRA_LDFLAGS -Wl,-Bdynamic,-lcurl,-Bstatic"
         ;;
       *)
         PHP_ADD_LIBRARY(curl, , EXTRA_LDFLAGS)
         ;;
     esac],
    [AC_MSG_ERROR([cannot find or include curl])])

  AC_CHECK_HEADER(time.h, [], [AC_MSG_ERROR([Cannot find or include time.h])])

  ddtrace_fat_ldflags="$EXTRA_LDFLAGS"
  if test "$ext_shared" = "yes"; then
    ddtrace_slim_export_symbols="$ext_builddir/ddtrace-slim.sym"
    cat "$ext_srcdir/ddtrace-extension.sym" > "$ddtrace_slim_export_symbols"

    case $host_os in
      linux*)
        cat "$ext_srcdir/ddtrace-extension-linux.sym" \
          >> "$ddtrace_slim_export_symbols"
      ;;
    esac

    ddtrace_fat_export_symbols="$ext_builddir/ddtrace-fat.sym"
    cat "$ddtrace_slim_export_symbols" \
      "$ext_srcdir/components-rs/libdatadog-php.sym" \
      "$ext_srcdir/components-rs/libdatadog-php-unix.sym" \
      > "$ddtrace_fat_export_symbols"

    case $host_os in
      linux*)
        cat "$ext_srcdir/components-rs/libdatadog-php-linux.sym" \
          >> "$ddtrace_fat_export_symbols"
      ;;
    esac

    dnl Only export the symbols selected above, which should all be marked as
    dnl DATADOG_PUBLIC in their source files.
    EXTRA_CFLAGS="$EXTRA_CFLAGS -fvisibility=hidden"
    ddtrace_slim_ldflags="$EXTRA_LDFLAGS -flto -fuse-linker-plugin"
    ddtrace_fat_ldflags="$ddtrace_slim_ldflags"

    case $host_os in
      linux*)
        dnl A fat Linux ddtrace.so is also the sidecar executable. When ld.so
        dnl executes it directly, it jumps to this ELF entry point.
        ddtrace_fat_ldflags="$ddtrace_fat_ldflags -Wl,-e,ddog_spawn_direct_entry"
      ;;
    esac

    if test "$PHP_DDTRACE_RUST_LIBRARY_SPLIT" = "no"; then
      EXTRA_LDFLAGS="$ddtrace_fat_ldflags -export-symbols $ddtrace_fat_export_symbols"
    else
      EXTRA_LDFLAGS="$ddtrace_slim_ldflags -export-symbols $ddtrace_slim_export_symbols"
    fi

    PHP_SUBST(EXTRA_CFLAGS)
    PHP_SUBST(EXTRA_LDFLAGS)
    PHP_SUBST(DDTRACE_SHARED_LIBADD)
  fi

  cat <<EOT >"$ext_srcdir/ext/version.h"
#ifndef PHP_DDTRACE_VERSION
#define PHP_DDTRACE_VERSION "$(cat "$ext_srcdir/VERSION")"
#endif
EOT

  PHP_ADD_INCLUDE([$ext_srcdir])

  PHP_ADD_BUILD_DIR([$ext_builddir/components-rs])

  PHP_ADD_BUILD_DIR([$ext_builddir/components])
  PHP_ADD_BUILD_DIR([$ext_builddir/components/log])
  PHP_ADD_BUILD_DIR([$ext_builddir/components/sapi])
  PHP_ADD_BUILD_DIR([$ext_builddir/components/string_view])
  PHP_ADD_BUILD_DIR([$ext_builddir/components/uuid])

  PHP_ADD_INCLUDE([$ext_srcdir/zend_abstract_interface])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/config])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/env])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/exceptions])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/headers])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/hook])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/interceptor])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/interceptor/php7])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/interceptor/php8])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/jit_utils])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/json])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/sandbox])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/sandbox/php7])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/sandbox/php8])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/uri_normalization])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/zai_assert])
  PHP_ADD_BUILD_DIR([$ext_builddir/zend_abstract_interface/zai_string])

  PHP_ADD_BUILD_DIR([$ext_builddir/tracer/hook])

  PHP_ADD_INCLUDE([$ext_srcdir/tracer/vendor])
  PHP_ADD_BUILD_DIR([$ext_builddir/tracer/vendor])

  PHP_ADD_INCLUDE([$ext_srcdir/tracer/vendor/mpack])
  PHP_ADD_BUILD_DIR([$ext_builddir/tracer/vendor/mpack])

  PHP_ADD_INCLUDE([$ext_srcdir/tracer/vendor/mt19937])
  PHP_ADD_BUILD_DIR([$ext_builddir/tracer/vendor/mt19937])

  dnl TODO Drop this in favor of sidecar
  PHP_ADD_INCLUDE([$ext_srcdir/src/dogstatsd])
  PHP_ADD_BUILD_DIR([$ext_builddir/src/dogstatsd])

  PHP_ADD_BUILD_DIR([$ext_builddir/ext])

  PHP_ADD_BUILD_DIR([$ext_builddir/tracer])
  PHP_ADD_BUILD_DIR([$ext_builddir/tracer/limiter])
  PHP_ADD_BUILD_DIR([$ext_builddir/tracer/priority_sampling])
  PHP_ADD_BUILD_DIR([$ext_builddir/tracer/tracer_tag_propagation])
  PHP_ADD_BUILD_DIR([$ext_builddir/tracer/integrations])
  PHP_ADD_INCLUDE([$ext_builddir/tracer/integrations])

  cat <<'EOT' >> Makefile.fragments
./modules/ddtrace.a: $(shared_objects_ddtrace) $(DDTRACE_SHARED_DEPENDENCIES)
	$(LIBTOOL) --mode=link $(CC) -static $(COMMON_FLAGS) $(CFLAGS_CLEAN) $(EXTRA_CFLAGS) $(LDFLAGS)  -o $@ -avoid-version -prefer-pic -module $(shared_objects_ddtrace)
EOT

  if test "$ext_shared" = "yes"; then
    all_object_files=$(for src in $ALL_DATADOG_SOURCES; do printf ' %s' "${src%?}lo"; done)
    all_object_files_absolute=$(for src in $ALL_DATADOG_SOURCES; do printf ' $(builddir)/%s' "$(dirname "$src")/$objdir/$(basename "${src%?}o")"; done)
    php_binary=$("$PHP_CONFIG" --php-binary)
    if test "$PHP_DDTRACE_SIDECAR_MOCKGEN" != "-"; then
      ddtrace_mockgen_invocation="HOST= TARGET= $PHP_DDTRACE_SIDECAR_MOCKGEN"
    else
      ddtrace_mockgen_invocation="cd \"$ext_srcdir/components-rs/php_sidecar_mockgen\"; HOST= TARGET= CARGO_TARGET_DIR=\$(builddir)/target_mockgen/ \$(DDTRACE_CARGO) run"
    fi
  fi

  if test "$PHP_DDTRACE_RUST_LIBRARY" != "-" && \
      test "$PHP_DDTRACE_RUST_LIBRARY_SPLIT" != "no"; then
    dnl libtool drops an unreferenced absolute DSO from shared_objects_ddtrace.
    dnl Pass it through as ordered linker arguments so it remains a DT_NEEDED
    dnl dependency without pulling its contents into ddtrace.so.
    case $host_os in
      linux*)
        DDTRACE_SHARED_LIBADD="$DDTRACE_SHARED_LIBADD \
-Wl,--push-state,-Bdynamic,--no-as-needed,$PHP_DDTRACE_RUST_LIBRARY,--pop-state"
        ;;
      darwin*)
        DDTRACE_SHARED_LIBADD="$DDTRACE_SHARED_LIBADD \
-Wl,-needed_library,$PHP_DDTRACE_RUST_LIBRARY"
        ;;
    esac
    ddtrace_rust_lib=""
  elif test "$PHP_DDTRACE_RUST_LIBRARY" != "-"; then
    ddtrace_rust_lib="$PHP_DDTRACE_RUST_LIBRARY"
  elif test "$PHP_DDTRACE_RUST_LIBRARY_SPLIT" != "no"; then
    ddtrace_rust_lib=""
  else
    dnl consider it debug if -g is specified (but not -g0)
    ddtrace_cargo_profile=$(test "$PHP_DDTRACE_RUST_DEBUG" != "no" && echo debug || echo tracer-release)
    ddtrace_rust_lib="\$(builddir)/target-common/$ddtrace_cargo_profile/libdatadog_php.a"
    if test "$PHP_DDTRACE_TRACER" != "no"; then
      ddtrace_cargo_features="--features tracer"
    else
      ddtrace_cargo_features="--no-default-features"
    fi

    cat <<EOT >> Makefile.fragments
$ddtrace_rust_lib: $( (find "$ext_srcdir/components-rs" -name "*.rs"; find "$ext_srcdir/sidecar" -name "*.rs" -o -name "Cargo.toml"; find "$ext_srcdir/appsec/helper-rust" -name "*.rs" -o -name "*.c" -o -name "Cargo.toml" -o -name "build.rs"; find "$ext_srcdir" -maxdepth 1 -name "Cargo.toml"; find "$ext_srcdir/../../libdatadog" -name "*.rs" -not -path "*/target/*"; find "$ext_srcdir/libdatadog" -name "*.rs" -not -path "*/target/*") 2>/dev/null | tr '\n' ' ' )
	(cd "$ext_srcdir"; PHP_CONFIG="\$(DDTRACE_PHP_CONFIG)" CARGO_FEATURES="$ddtrace_cargo_features" CARGO_TARGET_DIR=\$(builddir)/target-common/ SHARED=$(test "$ext_shared" = "yes" && echo 1) PROFILE="$ddtrace_cargo_profile" host_os="$host_os" DDTRACE_CARGO="\$(DDTRACE_CARGO)" $(if test "$PHP_DDTRACE_SANITIZE" != "no"; then echo COMPILE_ASAN=1; fi) sh ./compile_rust.sh \$(shell echo "\$(MAKEFLAGS)" | $EGREP -o "[[-]]j[[0-9]]+"))
EOT
  fi

  dnl Weaken PHP-origin symbols in all .o files before the link step so that
  dnl the resulting .so/.a naturally has weak references.
  if test "$ext_shared" = "yes"; then
    _ddtrace_weaken_tmp=$(mktemp)
    cat > "$_ddtrace_weaken_tmp" << WEAKEN
	($ddtrace_mockgen_invocation weaken-dynsym $all_object_files_absolute $php_binary)
WEAKEN
    sed -i $({ sed --version 2>&1 || echo ''; } | grep GNU >/dev/null || echo "''") -e "/\/ddtrace\.la:\ \\$/r $_ddtrace_weaken_tmp" Makefile.objects
    dnl run weaken only once, create a dependency on .la for .a
    echo "./modules/ddtrace.a: | ./ddtrace.la" >> Makefile.fragments
    rm -f "$_ddtrace_weaken_tmp"
  fi

  if test "$ext_shared" = "shared" || test "$ext_shared" = "yes"; then
    shared_objects_ddtrace="$ddtrace_rust_lib $shared_objects_ddtrace"
  else
    PHP_GLOBAL_OBJS="$ddtrace_rust_lib $PHP_GLOBAL_OBJS"
  fi

  dnl These flags are consumed by out-of-tree fat links.
  echo "$ddtrace_fat_ldflags $EXTRA_CFLAGS$ddtrace_ldflags_file_extra" > ddtrace-fat.ldflags
fi